 


(*flags
     (*flag 0         debug
     (*flag 1         sound 1=off
     (*flag 2         plank   1=over gap
     (*flag 3         trumpet/collapsing room  1=escaped
     (*flag 4         hat/secret  1=secret NOT under hat
     (*flag 5         policy 1=dispenced
     (*flag 6         soda 1=given to girl
     (*flag 7         pager 1=message waiting
     (*flag 8         misc: bad gift to packrat & rogues gallery
     (*flag 9         chain sawed 1=yes
     (*flag 10        fire 1=burning
     (*flag 11        organ stop used 1=yes
     (*flag 12        soggy dictionary 1=first message given
     (*flag 13        save 1=saved
     (*flag 14        death 1=died
     (*flag 15        rat 1=SKATE
     (*flag 16        rat 1=LAMP
     (*flag 17        rat 1=OIL
     (*flag 18        rat 1=KEY
     (*flag 19        rat 1=BUGLE
     (*flag 20        rat 1=TRUMPET
     (*flag 21        rat 1=CUTTER
     (*flag 22        rat 1=QUARTER
     (*flag 23        rat 1=HAT
     (*flag 24        rat 1=BOTTLE
     (*flag 25        rat 1=something was given this turn)
(*variables
     (*variable 1     default 155 (mens)
     (*variable 2     default 156 (womens)
     (*variable 3     genie appearances
     (*variable 4     NEWROOM
     (*variable 5     bathroom/tape  121/161
     (*variable 6     proposal series
     (*variable 7     rounds completed
     (*variable 8     thirsty  124/163
     (*variable 9     thirsty  125/164
     (*variable 10    thirsty  152/167
     (*variable 11    Insurance expires
     (*variable 12    Collapse messages (87 - 90)
     (*variable 13    Fire messages (63 - 65)
     (*variable 14    Bathroom messages (117 - 120)
     (*variable 15    Roof Jump - room number
     (*variable 16    Rogues Gallery
     (*variable 17    Bonus Score
(*counters
     (*counter 1      fire 0 - 9
     (*counter 2      collapsing room
     (*counter 3      dictionary soggy
     (*counter 4      bathroom
     (*counter 5      thirsty
     (*counter 6      insurance past due
     (*counter 7      Rogues Gallery

COMMAND ANY
NewLife
SetVariableTo 1 155
SetVariableTo 2 156
SetVariableTo 5 121
SetVariableTo 8 124
SetVariableTo 9 125
SetVariableTo 10 152
SetVariableTo 12 87
SetVariableTo 13 63
SetVariableTo 14 117
END_COMMAND

COMMAND YES
AtLocation 2
SetVariableTo 1 156
SetVariableTo 2 155
SetVariableTo 5 161
SetVariableTo 8 163
SetVariableTo 9 164
SetVariableTo 10 167
SwapLocations 321 322 (*actor/actress)
SwapLocations 324 325 (*zoo keepers)
GoToRoom 108
DoneWithTurn
END_COMMAND

COMMAND ANY
SendToRoom 223 8 (*clears head)
VariableGT 11 0  (*insurance)
SubtractFromVariable 11 1
VariableEquals 11 1  (*insurance)
TurnCounterOn 6 (*expired)
END_COMMAND

COMMAND ANY
AtLocation 110
NOT ObjectIsNumber 324
NOT ObjectIsNumber 325
NOT NOUNIsNumber 324
NOT NOUNIsNumber 325
NOT VerbIsDirection
IsSomewhere 314 (*plant)
Chance 60
RandomMessage 245 250
BlankLine
END_COMMAND

COMMAND ANY
CounterGT 7  7
PrintMessage 243 (*back to Gallery)
BlankLine
GoToRoom 110
MinusScore 100
TurnCounterOFF 7
TurnFlagOFF 8
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocationGT 110
FlagOFF 8  (*Rogues Gallery)
TurnCounterON 7
TurnFlagON 8
END_COMMAND

COMMAND ANY
AtLocation 64
IsCarrying 251
PrintMessage 31 (*fall)
BlankLine
TurnFlagON 14
END_COMMAND

COMMAND ANY
AtLocation 18
FirstVisitToRoom
PlusScore 100
END_COMMAND

COMMAND ANY
AtLocation 4
VerbIsDirection
IsCarrying 212
FlagOFF 9
PrintMessage 12 (*drop crowbar)
BlankLine
SendToRoom 212 4
END_COMMAND

COMMAND ANY
VerbIsDirection
FlagON 4
or
IsCarrying 280 (*secret)
PutInCurrentRoom 280
PrintMessage 18 (*secret fell)
BlankLine
TurnFlagOFF 4
MinusScore 10
END_COMMAND

COMMAND ANY
FlagOFF 13 (*not saved)
CounterGT 3 100 (*soggy dictionary)
TurnFlagOFF 12
TurnCounterOFF 3
END_COMMAND

COMMAND ANY
FlagON 13 (*saved)
CounterGT 3 300 (*soggy dictionary)
TurnFlagOFF 12
TurnCounterOFF 3
END_COMMAND

COMMAND ANY
VariableEquals 3 4 (*genie been to catwalk)
IsSomewhere 310 (*princess)
OR
IsSomewhere 312 (*prince)
SetVariableTo 3 5
SendToRoom 304 78 (*genie to stage)
END_COMMAND

COMMAND ANY
VariableEquals 3 5 (*Genie on stage/NOT seen)
VerbIsDirection
AtLocationGT 71
AtLocationLT 83
GoToRoom 78
SetVariableTo 3 6
PrintMessage 33
BlankLine
DoneWithTurn
END_COMMAND

COMMAND ANY
AtLocation 105  (*restroom)
CounterGT 4 0
PrintVariableMessage 5 (*made IT)
BlankLine
TurnCounterOFF 4
SendtoRoom 241 1 (*tape)
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND ANY
CounterEquals 2 3 (*collapse)
TurnCounterON 2
PrintVariableMessage 12
BlankLine
AddToVariable 12 1
END_COMMAND

COMMAND ANY
CounterEquals 1 4 (*fire)
TurnCounterON 1
PrintVariableMessage 13
BlankLine
AddToVariable 13 1
END_COMMAND

COMMAND ANY
CounterEquals 4 4 (*bathroom)
TurnCounterON 4
PrintVariableMessage 14
BlankLine
AddToVariable 14 1
END_COMMAND

COMMAND ANY
CounterEquals 5 5 (*thirsty)
PrintMessage 116
BlankLine
END_COMMAND

COMMAND ANY
CounterEquals 5 80
PrintVariableMessage 8
BlankLine
END_COMMAND

COMMAND ANY
CounterEquals 5 150
PrintvariableMessage 9
BlankLine
END_COMMAND

COMMAND ANY
CounterEquals 5 200
IsSomewhere 274 (*rushing stream)
PrintVariableMessage 10
PrintMessage 126 (*drown - bucket)
TurnFlagON 14
END_COMMAND

COMMAND ANY
CounterEquals 5 200
PrintVariableMessage 10
PrintMessage 128 (*die - shallow)
TurnFlagON 14
END_COMMAND

COMMAND ANY
VariableEquals 12 91 (*collapse)
OR
VariableEquals 13 66 (*fire)
OR
VariableEquals 14 121 (*bathroom)
OR
FlagON 14
ReDirectTo COMMANDS DRAWER
END_COMMAND

COMMAND ANY
VerbIsDirection
IsWearing 254 (*bucket)
NOT AtLocation 18
NOT AtLocation 19
PrintMessage 129 (*bucket on face)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND ANY
Chance 1
Chance 20
ClearScreen
PrintMessage 217
Delay 5
PrintMessage 218
BlankLine
Delay 2
LookAtRoom
END_COMMAND

COMMAND ANY
Chance 1
Chance 30
RandomMessage 214 216 (*ghosts)
delay 5
BlankLine
END_COMMAND

COMMAND ANY
Chance 1
Chance 40
Present 268
PrintMessage 239 (*pager beeping)
BlankLine
TurnFlagON 7
FlagOFF 1
TONE 1046 100
TONE 1568 100
TONE 1046 100
TONE 1568 100
TONE 1046 100
END_COMMAND

COMMAND debug
ToggleFlag 0          (*debug flag)
DoneWithTurn
END_COMMAND

COMMAND NEWROOM
NounToVariable 4
VariableGT 4 1
VariableLT 4 180
GoToVariableRoom 4
DoneWithTurn
END_COMMAND

COMMAND SCORE
PrintMessage 238
END_COMMAND

COMMAND HELP
AtLocationLT 110
NOT AtLocation 40
PrintMessage 241
END_COMMAND

COMMAND MAGIC_WORD
AtLocation 10 (*organ)
FlagOFF 11
PlusScore 100
TurnFlagOn 11
END_COMMAND

COMMAND SOUTH ANY
Present 208
OR
Present 290
PrintMessage 159 (*bump)
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND SOUTH ANY
AtLocation 33
MakeVarRoomNum 15
PrintMessage 49
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND SOUTH ANY
AtLocation 4 (*shop)
Present 305 (*cat)
GoToRoom 7
PrintMessage 130
BlankLine
Destroy 305
PlusScore 100
PutInCurrentRoom 253 (*knob)
DoneWithTurn
END_COMMAND

COMMAND SOUTH ANY
AtLocation 8
FlagOFF 2     (*plank missing)
Present 287
destroy 287
PrintMessage 9 (*putting plank down)
TurnFlagOn 2
BlankLine
GoToRoom 15   (*go south)
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND SOUTH ANY
AtLocation 8
FlagOff 2     (*plank missing)
PrintMessage 10 (*die)
TurnFlagON 14
END_COMMAND

COMMAND SOUTH ANY
AtLocationGT 76  (*down right)
AtLocationLT 80  (*down left)
IsLocated 298 54  (*curtain down)
PrintMessage 200  (*bounce back)
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND SOUTH ANY
AtLocation 82 (*apron)
IsLocated 298 77  (*curtain UP)
Chance 50
MinusScore 50
RelocateAll 1 94
RelocateAll 1000 94
TurnFlagOFF 4
GoToRoom 13   (*pit)
PrintMessage 6 (*fall down)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND SOUTH ANY
AtLocation 82 (*apron)
PrintMessage 199  (*bounce back)
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND SOUTH ANY
AtLocation 52 (*grid)
IsLocated 298 77 (*curtain up)
PrintMessage 79 (*fall)
BlankLine
TurnFlagON 14
END_COMMAND

COMMAND SOUTH ANY
AtLocation 35
FlagOFF 3 (*played trumpet)
TurnCounterON 2 (*collapse)
GoToRoom 49 (*collapse)
PrintMessage 86 (*enter room)
DoneWithTurn
END_COMMAND

COMMAND SOUTH ANY
IsWearing 254 (*bucket)
AtLocation 18
PrintMessage 129 (*bucket on face)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND SOUTH ANY
FlagOFF 15 (*rat)
AtLocation 16
SendToRoom 306 109
END_COMMAND

COMMAND SOUTH ANY
FlagOFF 17 (*rat)
AtLocation 27
SendToRoom 306 31
END_COMMAND

COMMAND SOUTH ANY
FLagON 14
ReDirectTo COMMANDS DRAWER
END_COMMAND

COMMAND SOUTHWEST ANY
AtLocation 53 (*grid)
IsLocated 298 77 (*curtain up)
PrintMessage 79 (*fall)
RedirectTO COMMANDS DRAWER
END_COMMAND

COMMAND NORTH ANY
AtLocation 56
MakeVarRoomNum 15
PrintMessage 49
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND NORTH ANY
AtLocation 16 (*hall)
RelocateAll 1 94
RelocateAll 1000 94
TurnFlagOFF 4
MinusScore 50
PrintMessage 147 (*elevator)
BlankLine
GoToRoom 44
DoneWithTurn
END_COMMAND

COMMAND NORTH ANY
AtLocation 108
RelocateAll 1 94
RelocateALL 1000 94
TurnFlagOFF 4
MinusScore 50
GoToRoom 91
PrintMessage 50 (*balcony fall)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND NORTH ANY
AtLocation 85  (*audience)
IsLocated 298 77  (*curtain up)
Chance 50
MinusScore 50
RelocateAll 1 94
RelocateAll 1000 94
TurnFlagOFF 4
PrintMessage 6 (*fall down)
BlankLine
GoToRoom 13
DoneWithTurn
END_COMMAND

COMMAND NORTH ANY
AtLocation 60
VariableEquals 3 1 (*lamp has been rubbed)
SetVariableTo 3 2
SendToRoom 302 51 (*genie to green room)
PrintMessage 26
END_COMMAND

COMMAND NORTH ANY
AtLocation 85  (*audience)
PrintMessage 8  (*bounce back)
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND NORTH ANY
AtLocation 82  (*apron)
IsLocated 298 54  (*curtain down)
PrintMessage 200  (*bounce back)
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND NORTH ANY
IsWearing 254 (*bucket)
AtLocation 19
PrintMessage 129 (*bucket on face)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND NORTH ANY
FlagOFF 16 (*rat)
AtLocation 93
SendToRoom 306 87
END_COMMAND

COMMAND NORTH ANY
FlagOFF 20 (*rat)
AtLocation 32
SendToRoom 306 56
END_COMMAND

COMMAND WEST ANY
Present 210
OR
Present 213
OR
Present 218
OR
Present 289
PrintMessage 159 (*bump)
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND WEST ANY
AtLocation 33
OR
AtLocation 32
MakeVarRoomNum 15
PrintMessage 49
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND WEST ANY
Present 274 (*rushing stream)
Not IsWearing 254 (*bucket)
IsWearing 269 (*scuba)
PrintMessage 53 (*drown - scuba)
TurnFlagON 14
END_COMMAND

COMMAND WEST ANY
FlagOFF 14
Present 274 (*rushing stream)
Not IsWearing 254
PrintMessage 51
TurnFlagON 14
END_COMMAND

COMMAND WEST ANY
FlagOFF 14
Present 274 (*rushing stream)
Present 309 (*girl)
PrintMessage 52 (*drown)
TurnFlagON 14
END_COMMAND

COMMAND WEST ANY
FlagOFF 14
Present 274 (*rushing stream)
Present 311 (*guy)
PrintMessage 157 (*drown)
TurnFlagON 14
END_COMMAND

COMMAND WEST ANY
FlagOFF 14
Present 274 (*rushing stream)
NOT Present 309
NOT Present 311
GoToRoom 18 (*hall)
PrintMessage 77 (*bucket)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND WEST ANY
Present 275
PrintMessage 54 (*ok)
BlankLine
END_COMMAND

COMMAND WEST ANY
AtLocation 44 (*shaft)
IsClosed 217 (*elevator doors)
PrintMessage 96 (*doors closed)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND WEST ANY
AtLocation 44
CloseIt 217
PrintMessage 97 (*slide shut)
BlankLine
END_COMMAND

COMMAND WEST ANY
AtLocation 65 (*catwalk)
IsCarrying 251 (*crate)
VariableEquals 3 2 (*has been to green room)
SendToRoom 303 65 (*genie #2)
PrintMessage 29
BlankLine
SetVariableTo 3 3
DoneWithTurn
END_COMMAND

COMMAND WEST ANY
AtLocation 55
IsLocated 298 77 (*curtain up)
PrintMessage 79 (*fall)
TurnFlagON 14
END_COMMAND

COMMAND WEST ANY
AtLocation 56 (*roof)
Present 279
IsOpen 279 (*window)
IsWearing 238 (*snowshoes)
GotoRoom 53
PrintMessage 83 (*thru window)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND WEST ANY
AtLocation 56
Present 279
IsOpen 279
PrintMessage 84 (*fall)
TurnFlagON 14
END_COMMAND

COMMAND WEST ANY
IsClosed 279
AtLocation 56
PrintMessage 172 (*can't)
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND WEST ANY
AtLocation 72 (*stage door)
VariableEquals 7 1 (*in round 2)
IsCarrying 293 (*chest)
PrintMessage 145 (*end round 2)
BlankLine
SendToRoom 300 20 (*cat)
SwapLocations 296 210 (*stage doors)
AddToVariable 7 1
PlusScore 2000
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND WEST ANY
AtLocation 72
VariableEquals 7 1
PrintMessage 146
BlankLine
DoneWithTurn
END_COMMAND

COMMAND WEST ANY
FlagOFF 23 (*rat)
AtLocation 13
SendToRoom 306 9
END_COMMAND

COMMAND WEST ANY
FlagOFF 22 (*rat)
AtLocation 45
SendToRoom 306 20
END_COMMAND

COMMAND WEST ANY
FlagON 14
ReDirectTo COMMANDS DRAWER
END_COMMAND

COMMAND EAST ANY
Present 214
OR
Present 216
OR
Present 219
PrintMessage 159 (*bump)
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND EAST ANY
AtLocation 33
OR
AtLocation 32
OR
AtLocation 56
MakeVarRoomNum 15
PrintMessage 49
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND EAST ANY
present 276 (*rushing stream)
Not IsWearing 254 (*bucket)
IsWearing 269 (*scuba)
PrintMessage 53 (*drown - scuba)
TurnFlagON 14
END_COMMAND

COMMAND EAST ANY
FlagOFF 14
Present 276 (*rushing stream)
Not IsWearing 254
PrintMessage 51
TurnFlagON 14
END_COMMAND

COMMAND EAST ANY
FlagOFF 14
Present 276 (*rushing stream)
Present 309 (*girl)
PrintMessage 52 (*drown)
TurnFlagON 14
END_COMMAND

COMMAND EAST ANY
FlagOFF 14
Present 276 (*rushing stream)
Present 311 (*guy)
PrintMessage 157 (*drown)
TurnFlagON 14
END_COMMAND

COMMAND EAST ANY
FlagOFF 14
Present 276 (*rushing stream)
NOT Present 309
NOT Present 311
GoToRoom 19 (*hall)
PrintMessage 78 (*bucket)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND EAST ANY
Present 277
PrintMessage 54 (*ok)
BlankLine
END_COMMAND

COMMAND EAST ANY
AtLocation 8 (*gap)
IsSomewhere 274 (*rushing stream)
NOT IsWearing 280
OR
AtLocation 8
IsSomewhere 274
FlagON 4
PrintMessage 169 (*warning)
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND EAST ANY
AtLocation 14
IsClosed 217
PrintMessage 96 (*elevator doors closed)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND EAST ANY
AtLocation 14
CloseIt 217
PrintMessage 97 (*close behind you)
BlankLine
END_COMMAND

COMMAND EAST ANY
AtLocation 88
FlagON 10 (*fire)
PrintMessage 58 (*fire blocks way)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND EAST ANY
FlagOFF 10
AtLocation 90 (*rehears)
IsCarrying 281 (*sign)
PrintMessage 62 (*fire start)
BlankLine
TurnCounterON 1 (*fire)
TurnFlagON 10 (*fire)
GotoRoom 84
ChangePassageway 4 47 (*charred hall)
GoToRoom 89
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND EAST ANY
AtLocation 28 (*guillotine)
Present 309 (*girl)
OR
Present 311 (*guy)
GoToRoom 27
ChangePassageway 3 48
PrintMessage 57 (*blade fell)
BlankLine
GoToRoom 48
DoneWithTurn
END_COMMAND

COMMAND EAST ANY
FlagOFF 19 (*rat)
AtLocation 14
SendToRoom 306 44
END_COMMAND

COMMAND EAST ANY
FlagOFF 21 (*rat)
AtLocation 29
SendToRoom 306 30
END_COMMAND

COMMAND EAST ANY
FlagOFF 24 (*rat)
AtLocation 37
SendToRoom 306 38
END_COMMAND

COMMAND EAST ANY
FlagON 14
ReDirectTo COMMANDS DRAWER
END_COMMAND

COMMAND DOWN ANY
IsCarrying 293 (*chest)
AtLocation 59 (*stairs)
OR
AtLocation 89 (*rehearse)
IsOpen 228 (*hatch)
PrintMessage 196 (*won't fit)
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND DOWN ANY
FlagOFF 18 (*rat)
AtLocation 89
SendToRoom 306 24
END_COMMAND

COMMAND DOWN ANY
AtLocation 89
IsOpen 228
CounterGT 1 0
TurnCounterOFF 1 (*fire)
TurnFlagOFF 10 (*fire)
GoToRoom 24 (*cave)
PrintMessage 66 (*fire safe)
BlankLine
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND DOWN ANY
AtLocation 89
IsOpen 228
GoToRoom 24 (*cave)
DoneWithTurn
END_COMMAND

COMMAND DOWN ANY
IsWearing 238
AtLocation 69
OR
AtLocation 79
OR
AtLocation 93
OR
AtLocation 59
OR
AtLocation 33
OR
AtLocation 16
OR
AtLocation 62
OR
AtLocation 58
PrintMessage 213
BlankLine
END_COMMAND

COMMAND UP ANY
AtLocation 76 (*stairs)
IsCarrying 293 (*chest)
PrintMessage 196 (*won't fit)
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND UP ANY
AtLocation 37 (*end of hall)
VariableEquals 7 0 (*in round 1)
PrintMessage 144 (*end round 1)
BlankLine
AddToVariable 7 1
SwapLocations 210 296 (*stage doors)
PlusScore 1000
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND SHOUT
ToggleFlag 1
FlagOFF 1
TONE 1397 300
END_COMMAND

COMMAND DARN ANY
NOT AtLocation 40
PrintMessage 99
BlankLine
MinusScore 100
DoneWithTurn
END_COMMAND

COMMAND FONDLE ANY
NOT AtLocation 40
NOT NOUNPresent
PrintMessage 93
BlankLine
DoneWithTurn
END_COMMAND

COMMAND FONDLE ANY
NOT AtLocation 40
NOUNIsNumber 309 (*girl)
OR
NOUNIsNumber 311 (*guy)
PrintMessage 188
BlankLine
DoneWithTurn
END_COMMAND

COMMAND FONDLE ANY
NOT AtLocation 40
NOUNIsNumber 301 (*Mary)
OR
NOUNIsNumber 310 (*princess)
OR
NOUNIsNumber 312 (*prince)
PrintMessage 76
BlankLine
DoneWithTurn
END_COMMAND

COMMAND FONDLE ANY
NOT AtLocation 40
NOUNIsCreature
PrintMessage 37
BlankLine
DoneWithTurn
END_COMMAND

COMMAND FONDLE ANY
NOT AtLocation 40
PrintMessage 1
BlankLine
DoneWithTurn
END_COMMAND

COMMAND BREAK A LEG
SendToRoom 223 1
PrintMessage 7
BlankLine
DoneWithTurn
END_COMMAND

COMMAND BREAK ANY
PrintMessage 13
Delay 5
PrintMessage 14
END_COMMAND

COMMAND KICK BUCKET
Present 254
PrintMessage 98
BlankLine
DoneWithTurn
END_COMMAND

COMMAND MOVE CHAIR
VariableGT 11 0
Present 206 (*chair)
Present 243 (*policy)
GoToRoom 101 (*hall)
ChangePassageway 2 102
Destroy 290 (*door)
Destroy 206 (*chair)
PrintMessage 151
Printmessage 40
BlankLine
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND MOVE CHAIR
Not Present 243
Present 206
PrintMessage 151
PrintMessage 39 (*no insurance)
ReDirectTo COMMANDS DRAWER
END_COMMAND

COMMAND MOVE CHAIR
Present 206
PrintMessage 151
PrintMessage 220 (*expired)
ReDirectTo COMMANDS DRAWER
END_COMMAND

COMMAND MAGIC_WORD SESAME
AtLocation 24
SendToRoom 223 1
END_COMMAND

COMMAND UNLOCK CHEST WITH KEY
Present 293
Present 246
IsLocked 293
SendToRoom 313 293
END_COMMAND

COMMAND OPEN SESAME
PrintMessage 43
BlankLine
DoneWithTurn
END_COMMAND

COMMAND OPEN DOORS
SomethingInside 298
AtLocation 44
OR
AtLocation 14
PrintMessage 92 (*door stuck)
BlankLine
AtLocation 44
NOT Present 286 (*cable)
GoToRoom 100
PrintMessage 240 (*saved)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND OPEN DOORS
NOT SomethingInside 298
AtLocation 14
OR
AtLocation 44
OpenIt 217
PrintMessage 95
BlankLine
DoneWithTurn
END_COMMAND

COMMAND OPEN DOOR
AtLocation 44
OR
AtLocation 106
RedirectTo OPEN DOORS
END_COMMAND

COMMAND OPEN HATCH ANY
NOUNPresent
Present 309
OR
Present 311
OpenIt 228 (*hatch)
PrintMessage 61
BlankLine
DoneWithTurn
END_COMMAND

COMMAND OPEN HATCH ANY
NOUNPresent
PrintMessage 59 (*too heavy)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PRY WINDOW WITH CROWBAR
NOUNPresent
ObjectPresent
OpenIt 279
destroy 212
PrintMessage 82 (*opens)
BlankLine
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND PRY WINDOW
NOUNPresent
PrintMessage 209
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PRY CRATE WITH CROWBAR
NOUNPresent
ObjectPresent
IsClosed 251
OpenIt 251
PrintMessage 32 (*opens)
BlankLine
PlusScore 100
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND PRY CRATE WITH CROWBAR
NOUNPresent
ObjectPresent
PrintMessage 154 (*already open)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PRY CRATE
NOUNPresent
PrintMessage 209
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GIVE ANY
NOT NOUNPresent
PrintMessage 93
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GIVE ANY
NOUNIsCreature
PrintMessage 5 (*smooth move)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GIVE ANY
NOT OBJECTPresent
PrintMessage 210
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GIVE ANY TO MARY
PrintMessage 136
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
NOUNIsNumber 221 (*dim bulb)
OR
NOUNIsNumber 234 (*apple)
OR
NOUNIsNumber 273 (*steak)
TurnFlagON 8
MinusScore 300
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
NOUNIsNumber 235 (*oilcan)
OR
NOUNIsNumber 252 (*lamp)
OR
NOUNIsNumber 267 (*ring)
OR
NOUNIsNumber 281 (*sign)
OR
NOUNIsNumber 236 (*quarter)
TurnFlagON 8
MinusScore 1100
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
AtLocation 24
PutInCurrentRoom 246 (*give KEY)
TurnFlagON 18
TurnFlagON 25
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
FlagOFF 25
NOUNIsNumber 229 (*hotdog)
OR
NOUNIsNumber 232 (*knife)
OR
NOUNIsNumber 258 (*hat)
OR
NOUNIsNumber 280 (*secret)
OR
NOUNIsNumber 292 (*1/2 hotdog)
TurnFlagON 8
MinusScore 1100
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
AtLocation 20
PutInCurrentRoom 236 (*give QUARTER)
TurnFlagON 22
TurnFlagON 25
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
AtLocation 38
PutInCurrentRoom 207 (*give BOTTLE)
TurnFlagON 24
TurnFlagON 25
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
FlagOFF 25
NOUNIsNumber 297 (*trumpet)
TurnFlagON 8
MinusScore 1100
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
AtLocation 30
PutInCurrentRoom 226 (*give CUTTER)
TurnFlagON 21
TurnFlagON 25
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
FlagOFF 25
NOUNIsNumber 231 (*makeup)
OR
NOUNIsNumber 279 (*window)
OR
NOUNIsNumber 286 (*cable)
TurnFlagON 8
MinusScore 1100
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
AtLocation 31
PutInCurrentRoom 235 (*give OILCAN)
TurnFlagON 17
TurnFlagON 25
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
FlagOFF 25
NOUNIsNumber 211 (*bugle)
OR
NOUNIsNumber 250 (*skate)
OR
NOUNIsNumber 251 (*crate)
OR
NOUNIsNumber 254 (*bucket)
OR
NOUNIsNumber 261 (*muliplication table)
OR
NOUNIsNumber 265 (*Pluto)
TurnFlagON 8
MinusScore 1100
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
AtLocation 56
PutInCurrentRoom 297 (*give TRUMPET)
TurnFlagON 20
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
AtLocation 44
PutInCurrentRoom 211 (*give BUGLE)
TurnFlagON 19
TurnCounterON 8
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
AtLocation 109
PutInCurrentRoom 250 (*give SKATE)
TurnFlagON 15
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
AtLocation 9
PutInCurrentRoom 258 (*give HAT)
TurnFlagON 23
TurnFlagON 25
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
AtLocation 87
PutInCurrentRoom 252 (*give LAMP)
TurnFlagON 16
TurnFlagON 25
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
FlagOFF 8
PrintMessage 36
BlankLine
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
FlagON 8
FlagOFF 1
TONE 65 500
TONE 73 100
TONE 78 300
TONE 65 300
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
FlagON 8
PrintMessage 219
BlankLine
TurnFlagOFF 8
END_COMMAND

COMMAND GIVE ANY TO PACKRAT
PlusScore 100
DestroyNoun
Destroy 306
TurnFlagOFF 25
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND GIVE SKATE TO GENIE
Present 302 (*genie #2)
destroy 302
destroy 250
SendToRoom 273 1 (*give
PrintMessage 27 (*steak)
BlankLine
PlusScore 100
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND GIVE ANY TO GENIE
Present 302
NOT NOUNWeightEquals 9
PrintMessage 46 (*reject)
PrintMessage 203 (*unwearable)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GIVE ANY TO GENIE
Present 302
PrintMessage 46
PrintMessage 201 (*size)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GIVE BUGLE TO GENIE
present 303 (*genie #3)
destroy 303
destroy 211
SetVariableTo 3 4 (*done with catwalk)
GoToRoom 83
changepassageway 3 65
changepassageway 4 63
GoToRoom 65
PrintMessage 30 (*bugle)
BlankLine
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND GIVE TRUMPET TO GENIE
Present 303
PrintMessage 46
PrintMessage 202 (*can't play)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GIVE ANY TO GENIE
Present 303
PrintMessage 46
PrintMessage 204 (*unplayable)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GIVE RECLAIM TO GENIE
Present 304 (*genie #3)
PrintMessage 34 (*win)
BlankLine
PlusScore 5000
PrintMessage 238
WinGame
DoneWithTurn
END_COMMAND

COMMAND GIVE RING TO GIRL
VariableEquals 6 1 (*played tape)
Destroy 267
PrintMessage 137 (*in mood)
BlankLine
AddToVariable 6 1
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND GIVE RING TO GIRL
CounterGT 4 0 (*bathroom)
PrintMessage 132 (*bath)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GIVE RING TO GIRL
CounterGT 5 0 (*thirsty)
PrintMessage 131
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GIVE RING TO GIRL
PrintMessage 136 (*ok/not in mood)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GIVE RING TO GUY
VariableEquals 6 1 (*played tape)
Destroy 267
PrintMessage 137 (*in mood)
BlankLine
AddToVariable 6 1
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND GIVE RING TO GUY
CounterGT 4 0 (*bathroom)
PrintMessage 132 (*bath)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GIVE RING TO GUY
CounterGT 5 0 (*thirsty)
PrintMessage 131
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GIVE RING TO GUY
PrintMessage 136 (*ok/not in mood)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GIVE DRINK TO GIRL
destroy 257
PrintMessage 122
BlankLine
TurnCounterOFF 5 (*thirsty)
TurnCounterOn 4 (*bathroom)
DoneWithTurn
END_COMMAND

COMMAND GIVE DRINK TO GUY
destroy 257
PrintMessage 162
BlankLine
TurnCounterOFF 5 (*thirsty)
TurnCounterOn 4 (*bathroom)
DoneWithTurn
END_COMMAND

COMMAND GIVE HOTDOG TO CAT
Present 300 (*cat)
Destroy 300
SendToRoom 305 20  (*happycat)
SwapLocations 229 292 (*hotdogs)
Printmessage 47
BlankLine
PlusScore 100
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND GIVE HOTDOG TO TOAD
Destroy 292
SwapLocations 307 308 (*toad)
Printmessage 48
BlankLine
PlusScore 100
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND GIVE ANY TO ANY
OBJECTIsCreature
PrintMessage 46
BlankLine
DoneWithTurn
END_COMMAND

COMMAND GIVE ANY
PrintMessage 205
BlankLine
DoneWithTurn
END_COMMAND

COMMAND DRINK DRINK
Present 257 (*drink)
NOT Present 311 (*guy)
NOT Present 309 (*girl)
PrintMessage 123 (*drink)
BlankLine
MinusScore 1000
DoneWithTurn
END_COMMAND

COMMAND DRINK DRINK
Present 257
PrintMessage 127 (*greedy)
ReDirectTo COMMANDS DRAWER
END_COMMAND

COMMAND DRINK WATER
Present 274
OR
Present 276
PrintMessage 206
BlankLine
DoneWithTurn
END_COMMAND

COMMAND DRINK WATER
Present 275
OR
Present 277
PrintMessage 207
BlankLine
DoneWithTurn
END_COMMAND

COMMAND DRINK ANY
NOUNPresent
NOUNIsCreature
PrintMessage 2
BlankLine
DoneWithTurn
END_COMMAND

COMMAND OIL WATER
ReDirectTo POUR OIL
END_COMMAND

COMMAND OIL HINGES
Present 216 (*door)
Present 235 (*oil)
PrintMessage 143 (*die)
ReDirectTo COMMANDS DRAWER
END_COMMAND

COMMAND GREASE HINGES
Present 216 (*door)
Present 231 (*makeup)
PrintMessage 150 (*open)
BlankLine
Destroy 216
Destroy 231
ChangePassageway 3 30
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND DISSOLVE GUM
Present 207
InRoom 247    (*gum here)
SwapLocations 247 284 (*note for gum)
PrintMessage 198 (*gum dissolved)
BlankLine
PlusScore 100
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND POUR BOTTLE
Present 207
InRoom 247    (*gum here)
SwapLocations 247 284 (*note for gum)
PrintMessage 198 (*gum dissolved)
BlankLine
PlusScore 100
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND POUR BOTTLE
Present 207
SendToRoom 207 51
PrintMessage 197 (*bottle in green room)
BlankLine
MinusScore 10
DoneWithTurn
END_COMMAND

COMMAND POUR OIL
NOT NOUNPresent
PrintMessage 93
BlankLine
DoneWithTurn
END_COMMAND

COMMAND POUR OIL
InRoom 274 (*stream)
OR
InRoom 276
SwapLocations 274 275 (*streams)
SwapLocations 276 277
PrintMessage 55 (*calm water)
BlankLine
Destroy 235
PlusScore 100
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND POUR OIL
PrintMessage 56  (*oil shoe)
BlankLine
MinusScore 10
END_COMMAND

COMMAND PUSH ANY
AtLocation 107
NOUNIsNumber 255
IsLocated 298 54
SendToRoom 298 77
PrintMessage 3  (*curtain going up)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PUSH ANY
AtLocation 107
NOUNIsNumber 255
IsLocated 298 77
SendToRoom 298 54
PrintMessage 4  (*curtain going up)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND TURN HEELS
NOUNPresent
Present 317
Destroy 317
PrintMessage 225
BlankLine
AddToVariable 17 1000
PrintMessage 238
Blankline
TurnCounterOFF 7
TurnFlagOFF 8
PrintMessage 244
BlankLine
GoToRoom 110
DoneWithTurn
END_COMMAND

COMMAND TURN TABLE
AtLocation 12
Present 261
destroy 261
PrintMessage 11 (*landslide)
BlankLine
GoToRoom 22   (*new storage)
ChangePassageway 1 7
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND TURN KNOB
Present 289 (*knobless door)
Present 253 (*knob)
PrintMessage 38 (*door opens)
BlankLine
Destroy 289 (*door)
ChangePassageway 4 50
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND TURN OFF LAMP
ReDirectTo EXTINGUISH LAMP
END_COMMAND

COMMAND TURN ON LAMP
ReDirectTo LIGHT LAMP
END_COMMAND

COMMAND THROW SWITCH
ReDirectTo LIGHT SWITCH
END_COMMAND

COMMAND PULL PLUG
ReDirectTo EXTINGUISH LAMP
END_COMMAND

COMMAND PLUG IN LAMP
ReDirectTo LIGHT LAMP
END_COMMAND

COMMAND PLUG LAMP IN
ReDirectTo LIGHT LAMP
END_COMMAND

COMMAND DROP PLUTO IN CRATE
ReDirectTo PUT PLUTO IN CRATE
END_COMMAND

COMMAND PUT ANY ON COUNTERWEIGHT
Present 298
NOUNPresent
SendNOUNToRoom 298
PrintMessage 60
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PUT PLANK ANY
AtLocation 8 (*gap)
Present 287 (*plank)
destroy 287
PrintMessage 9 (*putting plank down)
BlankLine
TurnFlagOn 2
GoToRoom 15   (*go south)
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND PUT SIGN IN MACHINE
Present 281 (*sign)
Present 295 (*new machine)
PutInCurrentRoom 257 (*drink)
SwapLocations 230 295 (*machines)
Destroy 281
PrintMessage 115 (*get drink)
BlankLine
PlusScore 100
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND PUT SECRET UNDER HAT
Present 280
Iswearing 258 (*hat)
WearIt 280 (*secret)
TurnFlagOFF 4
PrintMessage 15
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PUT SECRET UNDER HAT
Present 280
PrintMessage 19
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PUT SECRET ON HEAD
SendToRoom 223 1
ReDirectTo WEAR SECRET
END_COMMAND

COMMAND PUT SECRET ON
NOT Objectpresent
ReDirectTo WEAR SECRET
END_COMMAND

COMMAND PUT BULB IN SOCKET
Present 272
Present 221
IsOpen 271 (*spot open)
Destroy 221
SendToRoom 288 272
PrintMessage 35
BlankLine
PlusScore 100
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND PUT BULB IN SOCKET
Present 272
Present 288
PrintMessage 173
BlankLine
SendToRoom 288 272
DoneWithTurn
END_COMMAND

COMMAND PUT HAT ON HEAD
SendToRoom 223 1
ReDirectTo WEAR HAT
END_COMMAND

COMMAND PUT HAT ON SECRET
IsWearing 280
ReDirectTo WEAR HAT
END_COMMAND

COMMAND PUT HAT ON
NOT ObjectPresent
ReDirectTo WEAR HAT
END_COMMAND

COMMAND PUT KNOB ON DOOR
Present 289 (*knobless door)
Present 253 (*knob)
PrintMessage 38 (*door opens)
BlankLine
Destroy 289 (*door)
ChangePassageway 4 50
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND PUT DOOR UNDER DOOR
Present 220 (*fire door)
PrintMessage 43 (*not fair)
BlankLine
MinusScore 100
DoneWithTurn
END_COMMAND

COMMAND PUT TABLE ON TABLE
Present 263
NOUNIsNumber 263
PrintMessage 102 (*table vanishes)
BlankLine
Destroy 263
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND PUT CHEST ON TABLE
Present 293 (*chest)
Present 263
PrintMessage 101 (*chest gone)
ReDirectTo COMMANDS DRAWER
END_COMMAND

COMMAND PUT ANY ON TABLE
FlagOFF 1
Present 263
NOUNPresent
TONE 1397 300
TONE 2093 300
TONE 1047 100
TONE 1175 100
TONE 1319 100
TONE 1397 300
END_COMMAND

COMMAND PUT ANY ON TABLE
FlagOFF 1
Present 263
NOUNPresent
TONE 2093 300
TONE 1047 100
TONE 1175 100
TONE 1319 100
TONE 1397 600
PrintMessage 100 (*vanish)
BlankLine
SendNOUNToRoom 94
DoneWithTurn
END_COMMAND

COMMAND PROP DOOR WITH ANY
Present 220
PrintMessage 44 (*rephrase)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PUT ANY UNDER DOOR
Present 220
NOUNPresent
NOUNIsCreature
PrintMessage 5 (*smooth move)
BlankLine
MinusScore 200
DoneWithTurn
END_COMMAND

COMMAND PUT ANY UNDER DOOR
Present 220 (*fire door)
NOUNPresent
DestroyNOUN
SwapLocations 220 291
ChangePassageway 4 68 (*change halls)
PrintMessage 41 (*prop door)
BlankLine
PlusScore 100
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND PUT TAPE ON RECORDER
Present 241 (*tape)
Present 266 (*deck)
SendNOUNToRoom 266
PrintMessage 140 (*in for good)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PUT PLUTO IN CRATE
Present 251 (*crate)
Present 265 (*pluto)
IsClosed 251
Destroy 265
PrintMessage 148 (*shatter)
BlankLine
MinusScore 1000
DoneWithTurn
END_COMMAND

COMMAND PUT PLUTO IN CRATE
Present 251
Present 265
Destroy 265
SendToRoom 261 251
PrintMessage 149
BlankLine
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND PUT MAKEUP ON HINGES
ReDirectTo GREASE HINGES
END_COMMAND

COMMAND PUT BUCKET ON
SendToRoom 223 1
ReDirectTo WEAR BUCKET
END_COMMAND

COMMAND PUT QUARTER
Present 236 (*quarter)
Present 230 (*drink machine)
IsNowhere 243 (*policy)
Destroy 236
SwapLocations 230 295 (*machines)
PrintMessage 112 (*second panel lit)
BlankLine
MinusScore 1000
DoneWithTurn
END_COMMAND

COMMAND PUT QUARTER
Present 236 (*quarter)
Present 230 (*drink machine)
IsSomewhere 243
Destroy 236
SwapLocations 230 295 (*machines)
PrintMessage 112 (*second panel lit)
BlankLine
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND PUT QUARTER
Present 236
Present 242 (*vending machine)
FlagOFF 5 (*not policy)
PutInCurrentRoom 236
PutInCurrentRoom 243 (*policy
TurnFlagON 5 (*got policy)
SetVariableTo 11 100 (*expiration date)
PrintMessage 113
BlankLine
PlusScore 100
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND PUT QUARTER
Present 236
Present 242
FlagON 5 (*policy dispenced)
PutInCurrentRoom 236
PrintMessage 114 (*empty)
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND SCREW ANY
NOT Present 220 (*fire door)
NOUNPresent
NOUNIsCreature
PrintMessage 75
BlankLine
DoneWithTurn
END_COMMAND

COMMAND BUY DRINK
RedirectTo PUT QUARTER IN MACHINE
END_COMMAND

COMMAND BUY POLICY
ReDirectTo PUT QUARTER IN MACHINE
END_COMMAND

COMMAND WEAR HAT
Present 258 (*hat)
IsWearing 280 (*secret)
TurnFlagOFF 4
PrintMessage 15 (*put hat over secret)
WearNOUN
BlankLine
END_COMMAND

COMMAND WEAR SECRET
Present 280
Not IsWearing 280
Not IsWearing 258 (*hat)
PrintMessage 16 (*balance secret on head)
TurnFlagON 4
WearNOUN
DoneWithTurn
END_COMMAND

COMMAND WEAR SECRET
Present 280
Not IsWearing 280
IsWearing 258
PrintMessage 17 (*balance secret on hat)
TurnFlagON 4
WearNOUN
DoneWithTurn
END_COMMAND

COMMAND MARRY MARY
Present 301 (*Mary)
destroy 301
SendToRoom 265 1 (*carry pluto)
PrintMessage 20  (*mary to pluto)
BlankLine
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND MARRY RECORDER
FlagOFF 1
TONE 523 1000
TONE 699 750
TONE 699 250
TONE 699 1000
TONE 523 1000
TONE 784 750
TONE 659 250
TONE 699 1000
DoneWithTurn
END_COMMAND

COMMAND MARRY ANY
ReDirectTo PROPOSE TO $NOUN$
END_COMMAND

COMMAND SHAKE SPEAR
Present 270
SwapLocations 270 254 (*spear/bucket)
PrintMessage 22 (*pun)
BlankLine
PlusScore 100
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND RUB LAMP
Present 252 (*lamp)
VariableEquals 3 0 (*no appearance yet)
PrintMessage 23 (*1st appearance)
BlankLine
SetVariableTo 3 1
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND LIGHT ANY
NOT NOUNPresent
PrintMessage 93
BlankLine
DoneWithTurn
END_COMMAND

COMMAND LIGHT LAMP
VariableEquals 3 0 (*no appearance yet)
PrintMessage 24 (*light lamp)
PrintMessage 25 (*torched)
RedirectTo COMMANDS DRAWER
END_COMMAND

COMMAND LIGHT LAMP
IsOff 252
PrintMessage 24
BlankLine
END_COMMAND

COMMAND EXTINGUISH ANY
NOT NOUNPresent
PrintMessage 93
BlankLine
DoneWithTurn
END_COMMAND

COMMAND BLOW BOILER
IsSomewhere 284 (*note)
Present 201 (*boiler)
GoToRoom 26
ChangePassageway 4 45 (*new boiler room)
GoToRoom 45
PrintMessage 42 (*blow boiler)
BlankLine
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND BLOW BOILER
Present 201 (*boiler)
PrintMessage 111 (*no blow)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND BLOW ANY
NOUNPresent
NOUNIsCreature
PrintMessage 75
BlankLine
DoneWithTurn
END_COMMAND

COMMAND TAKE HAT OFF ANY
IsWearing 258
GetIt 258
TurnFlagON 4
END_COMMAND

COMMAND REMOVE HAT
IsWearing 280 (*secret)
TurnFlagON 4
END_COMMAND

COMMAND TAKE HACKSAW ANY
IsSomewhere 284 (*note)
Present 201 (*boiler)
GoToRoom 26
ChangePassageway 4 45 (*new boiler room)
GoToRoom 45
PrintMessage 42 (*blow boiler)
BlankLine
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND TAKE HACKSAW ANY
Present 201 (*boiler)
PrintMessage 111 (*no blow)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND TAKE TAPE ANY
Present 266
SomethingInside 266
PrintMessage 140 (*in for good)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND TAKE TABLE ANY
Present 261 (*mult. table)
Present 251 (*crate)
NOUNIsNumber 261
Destroy 251
SendToRoom 261 1
PrintMessage 171
BlankLine
DoneWithTurn
END_COMMAND

COMMAND FEED HOTDOG TO CAT
Present 300 (*cat)
Present 229 (*hotdog)
SwapLocations 300 305 (*cats)
SwapLocations 229 292 (*hotdogs)
Printmessage 47
BlankLine
PlusScore 100
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND FEED HOTDOG TO TOAD
Present 307 (*toad)
Present 292 (*1/2hotdog)
Destroy 292
SwapLocations 307 308 (*toad)
Printmessage 48
BlankLine
PlusScore 100
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND FEED ANY TO PLANT
NOUNIsNumber 310
OR
NOUNIsNumber 312
ObjectPresent
NOUNPresent
Destroy 314
PrintMessage 231
BlankLine
AddToVariable 17 10000
PrintMessage 238
BlankLine
TurnCounterOFF 7
TurnFlagOFF 8
GoToRoom 110
PrintMessage 168
BlankLine
DoneWithTurn
END_COMMAND

COMMAND FEED ANY TO PLANT
ObjectPresent
NOUNPresent
NOUNIsNumber 309
OR
NOUNIsNumber 311
PrintMessage 230
MinusScore 10000
ReDirectTo COMMANDS DRAWER
END_COMMAND

COMMAND FEED ANY
NOUNPresent
NOUNIsCreature
PrintMessage 208
BlankLine
DoneWithTurn
END_COMMAND

COMMAND FEED ANY
NOUNPresent
NOUNIsEdible
PrintMessage 211
BlankLine
DoneWithTurn
END_COMMAND

COMMAND FEED ANY
NOUNPresent
PrintMessage 94
BlankLine
DoneWithTurn
END_COMMAND

COMMAND EAT ANY
NOUNPresent
NOUNIsCreature
PrintMessage 2
BlankLine
DoneWithTurn
END_COMMAND

COMMAND EAT APPLE
Present 234
PrintMessage 107 (*apple)
BlankLine
Destroy 234
PlusScore 10
DoneWithTurn
END_COMMAND

COMMAND EAT HOTDOG
Present 229 (*hotdog)
or
Present 292 (*1/2hotdog)
destroyNOUN
PrintMessage 45
BlankLine
MinusScore 1000
DoneWithTurn
END_COMMAND

COMMAND EAT STEAK
Present 273
swaplocations 273 282
PrintMessage 28
BlankLine
DoneWithTurn
END_COMMAND

COMMAND CUT ANY WITH ANY
NOT NOUNPresent
PrintMessage 93 (*noun not here)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND CUT MIRROR WITH DIAMOND
OBJECTPresent
Destroy 200 (*mirror)
ChangePassageway 4 35 (*open to hall)
PrintMessage 104 (*cut)
BlankLine
PlusScore 100
GoToRoom 35
DoneWithTurn
END_COMMAND

COMMAND CUT MIRROR WITH RING
OBJECTPresent
PrintMessage 103 (*mirror fall)
ReDirectTO COMMANDS DRAWER
END_COMMAND

COMMAND CUT MIRROR WITH ANY
PrintMessage 105
BlankLine
DoneWithTurn
END_COMMAND

COMMAND CUT BOX WITH CUTTER
NOUNPresent
OBJECTPresent
PrintMessage 67 (*open box)
BlankLine
OpenIt 248
PutInCurrentRoom 249
PlusScore 100
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND CUT ROPE WITH KNIFE
OBJECTPresent
Destroy 232
SwapLocations 256 293 (*chests)
PrintMessage 80 (*success)
BlankLine
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND CUT CHAIN WITH HACKSAW
OBJECTPresent
FlagOFF 9
TurnFlagOn 9
PrintMessage 85
BlankLine
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND CUT CHAIN WITH HACKSAW
OBJECTPresent
PrintMessage 170 (*another link)
BlankLine
DoneWithTurn
MinusScore 10
END_COMMAND

COMMAND CUT WINDOW WITH ANY
PrintMessage 106
BlankLine
DoneWithTurn
END_COMMAND

COMMAND CUT ANY
PrintMessage 209
BlankLine
DoneWithTurn
END_COMMAND

COMMAND KISS CAT
Present 300
PrintMessage 68 (*nose nip)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND KISS CAT
Present 305
PrintMessage 69 (*nuzzle)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND KISS FROG
Present 307
PrintMessage 70 (*toad breath)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND KISS FROG
Present 308
VariableEquals 1 155 (*actor)
PrintMessage 71 (*POOF)
BlankLine
SwapLocations 308 309
TurnCounterON 5
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND KISS FROG
Present 308
PrintMessage 158 (*POOF)
BlankLine
SwapLocations 308 311
TurnCounterOn 5
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND KISS GIRL
VariableEquals 6 3 (*proposed)
Present 309
PrintMessage 139 (*POOF 2)
BlankLine
SwapLocations 309 310 (*girl/princess)
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND KISS GIRL
Present 309
CounterGT 5 25 (*thirsty)
PrintMessage 131
BlankLine
DoneWithTurn
END_COMMAND

COMMAND KISS GIRL
Present 309
CounterGT 4 0 (*bathroom)
PrintMessage 132
BlankLine
DoneWithTurn
END_COMMAND

COMMAND KISS PRINCESS
Present 310
PrintMessage 73 (*turn on)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND KISS GUY
VariableEquals 6 3 (*proposed)
Present 311
PrintMessage 166 (*POOF 2)
BlankLine
SwapLocations 311 312 (*guy/prince)
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND KISS GUY
Present 311
CounterGT 5 25 (*thirsty)
PrintMessage 131
BlankLine
DoneWithTurn
END_COMMAND

COMMAND KISS GUY
Present 311
CounterGT 4 0 (*bathroom)
PrintMessage 132
BlankLine
DoneWithTurn
END_COMMAND

COMMAND KISS ANY
NOUNPresent
NOUNIsNumber 311
OR
NOUNIsNumber 309
PrintMessage 72 (*toad breath)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND KISS PRINCE
Present 312
PrintMessage 160 (*turn on)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND KISS MARY
NOUNPresent
PrintMessage 188
BlankLine
DoneWithTurn
END_COMMAND

COMMAND KISS GENIE
NOUNPresent
PrintMessage 74 (*no)
BlankLine
MinusScore 10
DoneWithTurn
END_COMMAND

COMMAND KISS TOTO
NOUNPresent
PrintMessage 221 (*no 3)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND KISS ANY
NounIsCreature
NOUNPresent
PrintMessage 75 (*no 2)
BlankLine
MinusScore 10
DoneWithTurn
END_COMMAND

COMMAND PROPOSE TO GIRL
Present 309 (*girl)
CounterGT 4 0 (*bathroom)
PrintMessage 132 (*bath)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PROPOSE TO GIRL
Present 309 (*girl)
CounterGT 5 0 (*thirsty)
PrintMessage 131 (*bath)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PROPOSE TO GIRL
Present 309 (*girl)
VariableEquals 6 2 (*gave ring)
PrintMessage 135 (*accept)
BlankLine
AddToVariable 6 1
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND PROPOSE TO GIRL
Present 309 (*girl)
VariableEquals 6 1 (*no ring)
PrintMessage 134 (*in mood)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PROPOSE TO GIRL
Present 309 (*girl)
PrintMessage 133 (*no tape)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PROPOSE TO GUY
Present 311 (*guy)
CounterGT 4 0 (*bathroom)
PrintMessage 132 (*bath)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PROPOSE TO GUY
Present 311 (*guy)
CounterGT 5 0 (*thirsty)
PrintMessage 131 (*bath)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PROPOSE TO GUY
Present 311 (*guy)
VariableEquals 6 2 (*gave ring)
PrintMessage 165 (*accept)
BlankLine
PlusScore 100
AddToVariable 6 1
DoneWithTurn
END_COMMAND

COMMAND PROPOSE TO GUY
Present 311 (*guy)
VariableEquals 6 1 (*no ring)
PrintMessage 134 (*in mood)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PROPOSE TO GUY
Present 311 (*guy)
PrintMessage 133 (*no tape)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PROPOSE ANY
PrintMessage 210
BlankLine
DoneWithTurn
END_COMMAND

COMMAND ANSWER PAGER
FlagON 7
Present 268
RandomMessage 232 237
BlankLine
TurnFlagOFF 7
DoneWithTurn
END_COMMAND

COMMAND PLAY TRUMPET
FlagOFF 1
Present 297
PrintMessage 108 (*trumpet)
BlankLine
TONE 262 200
TONE 293 200
TONE 311 200
TONE 349 200
TONE 392 200
TONE 311 200
END_COMMAND

COMMAND PLAY TRUMPET
FlagOFF 1
Present 297
TONE 392 400
TONE 349 200
TONE 293 200
TONE 349 400
TONE 392 200
TONE 311 200
TONE 392 400
END_COMMAND

COMMAND PLAY TRUMPET
Present 297
AtLocation 49
PrintMessage 91 (*play)
BlankLine
TurnFlagON 3 (*trumpet blown)
TurnCounterOff 2 (*collapse)
GoToRoom 41 (*Collapsed room)
PlusScore 100
DoneWithTurn
END_COMMAND

COMMAND PLAY TRUMPET
Present 297
DoneWithTurn
END_COMMAND

COMMAND PLAY ORGAN
Present 240
FlagOFF 1
TONE 33 1000
TONE 49 1000
TONE 46 1000
TONE 37 1000
TONE 33 1000
TONE 39 1000
TONE 44 1000
TONE 35 2000
END_COMMAND

COMMAND PLAY ORGAN
Present 240
PrintMessage 110 (*organ)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PLAY BUGLE
Present 211
FlagOFF 1
TONE 262  500
TONE 294  500
TONE 330  500
TONE 349  500
TONE 392  500
TONE 440  500
TONE 494  500
TONE 523  1000
END_COMMAND

COMMAND PLAY BUGLE
NOT Present 316
Present 211
PrintMessage 109 (*bugle)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PLAY BUGLE
NOUNPresent
Present 316 (*pirate)
PrintMessage 109
BlankLine
Destroy 316
PrintMessage 224
BlankLine
AddToVariable 17 1000
PrintMessage 238
Blankline
TurnCounterOFF 7
TurnFlagOFF 8
GotoRoom 110
DoneWithTurn
END_COMMAND

COMMAND PLAY TAPE
AtLocation 97 (*booth)
Present 241 (*tape)
SomethingInside 266
VariableEquals 6 0 (*not played yet)
AddToVariable 6 1
PrintMessage 141 (*wispy look)
BlankLine
PlusScore 100
ReDirectTo MARRY RECORDER
END_COMMAND

COMMAND PLAY TAPE
AtLocation 97 (*booth)
SomethingInside 266
PrintMessage 142 (*once again)
BlankLine
ReDirectTo MARRY RECORDER
END_COMMAND

COMMAND PLAY TAPE
AtLocation 97
Present 241
PrintMessage 138 (*not in deck)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND PLAY RECORDER
Present 241
Present 266
ReDirectTo PLAY TAPE
END_COMMAND

COMMAND SIGN FOR DRINK
Present 281 (*sign)
Present 295 (*new machine)
PutInCurrentRoom 257 (*drink)
SwapLocations 230 295 (*machines)
Destroy 281
PrintMessage 115 (*get drink)
BlankLine
PlusScore 100
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND LOOK AT DICTIONARY
AtLocation 81
PrintMessage 189
BlankLine
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
FlagON 13 (*saved)
AtLocation 81
CounterGT 3 0
PrintMessage 195 (*saved)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
CounterGT 3 2
FlagOFF 12 (*1st message)
PrintMessage 192 (*falling apart)
BlankLine
TurnFlagON 12
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
CounterGT 3 2
PrintMessage 193 (*still soggy)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
PrintMessage 194 (*looking up OBJECT)
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
CounterEquals 3 0
TurnCounterON 3
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
NOUNIsCreature
PrintMessage 174
MinusScore 200
PrintMessage 191
BlankLine
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
NOUNIsEdible
PrintMessage 175
MinusScore 200
PrintMessage 191
BlankLine
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
NOUNWeightEquals 4
PrintMessage 176
PrintMessage 191
MinusScore 200
BlankLine
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
NOUNWeightEquals 5
PrintMessage 177
PrintMessage 191
MinusScore 200
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
NOUNWeightEquals 8
PrintMessage 178
PrintMessage 191
BlankLine
MinusScore 200
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
NOUNWeightEquals 9
PrintMessage 179
PrintMessage 191
BlankLine
MinusScore 200
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
NOUNWeightEquals 10
PrintMessage 180
PrintMessage 191
BlankLine
MinusScore 200
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
NOUNWeightEquals 15
PrintMessage 181
PrintMessage 191
BlankLine
MinusScore 200
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
NOUNWeightEquals 16
PrintMessage 182
PrintMessage 191
BlankLine
MinusScore 200
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
NOUNWeightEquals 17
PrintMessage 183
PrintMessage 191
BlankLine
MinusScore 200
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
NOUNWeightEquals 18
PrintMessage 184
PrintMessage 191
BlankLine
MinusScore 200
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
NOUNWeightEquals 19
PrintMessage 185
PrintMessage 191
BlankLine
MinusScore 200
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
NOUNWeightEquals 20
PrintMessage 186
PrintMessage 191
BlankLine
MinusScore 200
DoneWithTurn
END_COMMAND

COMMAND LOOK UP ANY
AtLocation 81
NOUNWeightLT 4
PrintMessage 187
PrintMessage 191
BlankLine
MinusScore 200
DoneWithTurn
END_COMMAND

COMMAND LOOK IN CRATE
Present 251
IsOpen 251
IsNowhere 261
PrintMessage 153 (*dog gone)
BlankLine
DoneWithTurn
END_COMMAND

COMMAND LOOK IN CHEST
Present 293
IsOpen 293
IsLocated 313 293 (*ToTo)
PutInCurrentRoom 313
PrintMessage 21 (*Toto returns)
AddToVariable 17 5000
BlankLine
PrintMessage 238
BlankLine
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND TALK TO ZOOKEEPER
Present 324
OR
Present 325
RandomMessage 245 250
BlankLine
DoneWithTurn
END_COMMAND

COMMAND READ QUARTER TO BARBER
NOUNPResent
ObjectPresent
FlagOFF 1
TONE 1397 500
TONE 1047 250
TONE 1047 250
TONE 1175 500
TONE 1047 750
TONE 1319 500
TONE 1397 500
END_COMMAND

COMMAND READ QUARTER TO BARBER
NOUNPResent
ObjectPresent
PrintMessage 223
BlankLine
Destroy 315
AddToVariable 17 1000
PrintMessage 238
Blankline
TurnCounterOFF 7
TurnFlagOFF 8
GoToRoom 110
PrintMessage 244
BlankLine
DoneWithTurn
END_COMMAND

COMMAND READ HACKSAW TO JANITOR
NOUNPResent
ObjectPresent
PrintMessage 226
BlankLine
Destroy 318
AddToVariable 17 1000
PrintMessage 238
Blankline
TurnCounterOFF 7
TurnFlagOFF 8
PrintMessage 244
BlankLine
GoToRoom 110
DoneWithTurn
END_COMMAND

COMMAND READ SCRIPT TO CRITIC
NOUNPResent
ObjectPresent
PrintMessage 227
BlankLine
Destroy 319
AddToVariable 17 1000
PrintMessage 238
Blankline
TurnCounterOFF 7
TurnFlagOFF 8
PrintMessage 244
BlankLine
GoToRoom 110
DoneWithTurn
END_COMMAND

COMMAND READ POLICY TO AGENT
NOUNPResent
ObjectPresent
PrintMessage 228
BlankLine
Destroy 320
AddToVariable 17 1000
PrintMessage 238
Blankline
TurnCounterOFF 7
TurnFlagOFF 8
PrintMessage 244
BlankLine
GoToRoom 110
DoneWithTurn
END_COMMAND

COMMAND READ SECRET TO ANY
NOUNPresent
Present 321
OR
Present 322
PrintMessage 229
BlankLine
Destroy 321
Destroy 322
AddToVariable 17 1000
PrintMessage 238
Blankline
TurnCounterOFF 7
TurnFlagOFF 8
PrintMessage 244
BlankLine
GoToRoom 110
DoneWithTurn
END_COMMAND

COMMAND READ SECRET
AtLocation 9
Present 280
RelocateAll 9 8
GoToRoom 8
PrintMessage 212
BlankLine
DoneWithTurn
END_COMMAND

COMMAND READ ANY
NOUNPresent
NOUNIsCreature
PrintMessage 1
BlankLine
DoneWithTurn
END_COMMAND

COMMAND READ DICTIONARY
FlagON 13 (*saved)
CounterGT 3 0
AtLocation 81
PrintMessage 195
BlankLine
DoneWithTurn
END_COMMAND

COMMAND READ DICTIONARY
CounterGT 3 2
AtLocation 81
PrintMessage 192
BlankLine
DoneWithTurn
END_COMMAND

COMMAND READ DICTIONARY
AtLocation 81
CounterEquals 3 0
TurnCounterOn 3
END_COMMAND

COMMAND READ DICTIONARY
AtLocation 81
PrintMessage 190
RandomMessage 174 187
BlankLine
DoneWithTurn
END_COMMAND

COMMAND READ DOOR
AtLocation 98
PrintVariableMessage 1
BlankLine
DoneWithTurn
END_COMMAND

COMMAND READ DOOR
AtLocation 105
PrintVariableMessage 2
BlankLine
DoneWithTurn
END_COMMAND

COMMAND ATTACK ANY
AtLocationLT 111
NOUNPresent
NOUNIsCreature
PrintMessage 81
BlankLine
MinusScore 500
DoneWithTurn
END_COMMAND

COMMAND COMMANDS DRAWER
FlagOFF 1
TONE 35 900
TONE 35 600
TONE 35 300
TONE 35 900
TONE 41 600
TONE 39 300
END_COMMAND

COMMAND COMMANDS DRAWER
FlagOFF 1
TONE 39 600
TONE 35 300
TONE 35 600
TONE 33 300
TONE 35 1200
END_COMMAND

COMMAND COMMANDS DRAWER
BlankLine
PrintMessage 238
EndGame
DoneWithTurn
END_COMMAND

COMMAND COMMANDS ANY
PrintMessage 242
BlankLine
DoneWithTurn
END_COMMAND

COMMAND SAVE ANY
CounterGT 3 0 (*read dictionary)
CounterLT 3 5
AtLocation 81
OR
AtLocationGT 74
AtLocationLT 77
TurnFlagON 13
END_COMMAND

COMMAND RESTORE ANY
FlagOn 13 (*saved game)
AtLocation 81
OR
AtLocationGT 74
AtLocationLT 77
PrintMessage 222
BlankLine
END_COMMAND